GNU Info
(zsh.info)Redirection
Redirection
***********
If a command is followed by & and job control is not active, then the
default standard input for the command is the empty file /dev/null.
Otherwise, the environment for the execution of a command contains the
file descriptors of the invoking shell as modified by input/output
specifications.
The following may appear anywhere in a simple command or may precede or
follow a complex command. Expansion occurs before WORD or DIGIT is
used except as noted below. If the result of substitution on WORD
produces more than one filename, redirection occurs for each separate
filename in turn.
< WORD
Open file WORD for reading as standard input.
<> WORD
Open file WORD for reading and writing as standard input. If the
file does not exist then it is created.
> WORD
Open file WORD for writing as standard output. If the file does
not exist then it is created. If the file exists, and the CLOBBER
option is unset, this causes an error; otherwise, it is truncated
to zero length.
>| WORD
>! WORD
Same as >, except that the file is truncated to zero length if it
exists, even if CLOBBER is unset.
>> WORD
Open file WORD for writing in append mode as standard output. If
the file does not exist, and the CLOBBER option is unset, this
causes an error; otherwise, the file is created.
>>| WORD
>>! WORD
Same as >>, except that the file is created if it does not exist,
even if CLOBBER is unset.
<<[-] WORD
The shell input is read up to a line that is the same as WORD, or
to an end-of-file. No parameter expansion, command substitution or
filename generation is performed on WORD. The resulting document,
called a _here-document_, becomes the standard input.
If any character of WORD is quoted with single or double quotes or
a `\', no interpretation is placed upon the characters of the
document. Otherwise, parameter and command substitution occurs,
`\' followed by a newline is removed, and `\' must be used to
quote the characters `\', `$', ``' and the first character of WORD.
If <<- is used, then all leading tabs are stripped from WORD and
from the document.
<<< WORD
Perform shell expansion on WORD and pass the result to standard
input. This is known as a _here-string_.
<& NUMBER
>& NUMBER
The standard input/output is duplicated from file descriptor
NUMBER (see man page dup2(2)).
<& -
>& -
Close the standard input/output.
<& p
>& p
The input/output from/to the coprocess is moved to the standard
input/output.
>& WORD
&> WORD
(Except where `>& WORD' matches one of the above syntaxes; `&>'
can always be used to avoid this ambiguity.) Redirects both
standard output and standard error (file descriptor 2) in the
manner of `> WORD'. Note that this does _not_ have the same
effect as `> WORD 2>&1' in the presence of multios (see the
section below).
>&| WORD
>&! WORD
&>| WORD
&>! WORD
Redirects both standard output and standard error (file descriptor
2) in the manner of `>| WORD'.
>>& WORD
&>> WORD
Redirects both standard output and standard error (file descriptor
2) in the manner of `>> WORD'.
>>&| WORD
>>&! WORD
&>>| WORD
&>>! WORD
Redirects both standard output and standard error (file descriptor
2) in the manner of `>>| WORD'.
If one of the above is preceded by a digit, then the file descriptor
referred to is that specified by the digit instead of the default 0 or
1. The order in which redirections are specified is significant. The
shell evaluates each redirection in terms of the (_file descriptor_,
_file_) association at the time of evaluation. For example:
... 1>FNAME 2>&1
first associates file descriptor 1 with file FNAME. It then associates
file descriptor 2 with the file associated with file descriptor 1 (that
is, FNAME). If the order of redirections were reversed, file
descriptor 2 would be associated with the terminal (assuming file
descriptor 1 had been) and then file descriptor 1 would be associated
with file FNAME.
Multios
=======
If the user tries to open a file descriptor for writing more than once,
the shell opens the file descriptor as a pipe to a process that copies
its input to all the specified outputs, similar to `tee', provided the
MULTIOS option is set, as it is by default. Thus:
date >foo >bar
writes the date to two files, named `foo' and `bar'. Note that a pipe
is an implicit redirection; thus
date >foo | cat
writes the date to the file `foo', and also pipes it to cat.
If the MULTIOS option is set, the word after a redirection operator is
also subjected to filename generation (globbing). Thus
: > *
will truncate all files in the current directory, assuming there's at
least one. (Without the MULTIOS option, it would create an empty file
called `*'.) Similarly, you can do
echo exit 0 >> *.sh
If the user tries to open a file descriptor for reading more than once,
the shell opens the file descriptor as a pipe to a process that copies
all the specified inputs to its output in the order specified, similar
to `cat', provided the MULTIOS option is set. Thus
sort <foo <fubar
or even
sort <f{oo,ubar}
is equivalent to `cat foo fubar | sort'.
Note that a pipe is an implicit redirection; thus
cat bar | sort <foo
is equivalent to `cat bar foo | sort' (note the order of the inputs).
If the MULTIOS option is _un_set, each redirection replaces the
previous redirection for that file descriptor. However, all files
redirected to are actually opened, so
echo foo > bar > baz
when MULTIOS is unset will truncate bar, and write `foo' into baz.
Redirections with no command
============================
When a simple command consists of one or more redirection operators and
zero or more parameter assignments, but no command name, zsh can behave
in several ways.
If the parameter NULLCMD is not set or the option CSH_NULLCMD is set,
an error is caused. This is the `csh' behavior and CSH_NULLCMD is set
by default when emulating `csh'.
If the option SH_NULLCMD is set, the builtin `:' is inserted as a
command with the given redirections. This is the default when emulating
`sh' or `ksh'.
Otherwise, if the parameter NULLCMD is set, its value will be used as a
command with the given redirections. If both NULLCMD and READNULLCMD
are set, then the value of the latter will be used instead of that of
the former when the redirection is an input. The default for NULLCMD
is `cat' and for READNULLCMD is `more'. Thus
< file
shows the contents of file on standard output, with paging if that is a
terminal. NULLCMD and READNULLCMD may refer to shell functions.
automatically generated by info2www version 1.2.2.9