GNU Info

(gnuplot.info)with

---

Prev: title Up: plot

---

Enter node , (file) or (file)node

 Functions and data may be displayed in one of a large number of styles.
 The `with` keyword provides the means of selection.

 Syntax:
       with <style> { {linestyle | ls <line_style>}
                      | {{linetype | lt <line_type>}
                         {linewidth | lw <line_width>}
                         {pointtype | pt <point_type>}
                         {pointsize | ps <point_size>}} }

 where <style> is either `lines` (Note: lines ),  `points` (Note: points ),
  `linespoints` (Note: linespoints ),  `impulses` (Note: impulses ),
  `dots` (Note: dots ), `steps` (Note: steps ),  `fsteps`
 (Note: fsteps ),  `histeps` (Note: histeps ),  `errorbars`
 (Note: errorbars ),  `xerrorbars` (Note: xerrorbars ),  `yerrorbars`
 (Note: yerrorbars ), `xyerrorbars` (Note: xyerrorbars ),  `boxes`
 (Note: boxes ),  `boxerrorbars` (Note: boxerrorbars ),  `boxxyerrorbars`
 (Note: boxxyerrorbars ),  `financebars` (Note: financebars ),
 `candlesticks` (Note: candlesticks ) or  `vector` (Note: vector ).  Some
 of these styles require additional information.  See `set style <style>` for
 details of each style.

 Default styles are chosen with the `set function style`
 (Note: function style ) and  `set data style` (Note: data style )
 commands.

 By default, each function and data file will use a different line type and
 point type, up to the maximum number of available types.  All terminal
 drivers support at least six different point types, and re-use them, in
 order, if more are required.  The LaTeX driver supplies an additional six
 point types (all variants of a circle), and thus will only repeat after 12
 curves are plotted with points.  The PostScript drivers (`postscript`
 (Note: postscript )) supplies a total of 64.

 If you wish to choose the line or point type for a single plot, <line_type>
 and <point_type> may be specified.  These are positive integer constants (or
 expressions) that specify the line type and point type to be used for the
 plot.  Use `test` (Note: test ) to display the types available for your
 terminal.

 You may also scale the line width and point size for a plot by using
 <line_width> and <point_size>, which are specified relative to the default
 values for each terminal.  The pointsize may also be altered globally---see
 `set pointsize` (Note: pointsize ) for details.  But note that both
 <point_size> as set here and as set by `set pointsize` multiply the default
 point size---their effects are not cumulative.  That is, `set pointsize 2;
 plot x w p ps 3` will use points three times default size, not six.

 If you have defined specific line type/width and point type/size combinations
 with `set linestyle` (Note: linestyle ), one of these may be selected by
 setting <line_style> to the index of the desired style.

 The keywords may be abbreviated as indicated.

 Note that the `linewidth` (Note: linewidth ) and pointsize options are not
 supported by all terminals.

 Examples:

 This plots sin(x) with impulses:
       plot sin(x) with impulses

 This plots x with points, x**2 with the default:
       plot x*y w points, x**2 + y**2

 This plots tan(x) with the default function style, file "data.1" with lines:
       plot [ ] [-2:5] tan(x), 'data.1' with l

 This plots "leastsq.dat" with impulses:
       plot 'leastsq.dat' w i

 This plots the data file "population" with boxes:
       plot 'population' with boxes

 This plots "exper.dat" with errorbars and lines connecting the points
 (errorbars require three or four columns):
       plot 'exper.dat' w lines, 'exper.dat' notitle w errorbars

 This plots sin(x) and cos(x) with linespoints, using the same line type but
 different point types:
       plot sin(x) with linesp lt 1 pt 3, cos(x) with linesp lt 1 pt 4

 This plots file "data" with points of type 3 and twice usual size:
       plot 'data' with points pointtype 3 pointsize 2

 This plots two data sets with lines differing only by weight:
       plot 'd1' t "good" w l lt 2 lw 3, 'd2' t "bad" w l lt 2 lw 1

 See `set style` (Note: style ) to change the default styles.